10 REM LOTTOZAHLEN
20 REM (W) 9/1992 THOMAS KNEISSLER
30 REM
40 DIM F(49)
50 POKE 53280,0:POKE 53281,0:POKE 646,15
60 PRINT CHR$(14);CHR$(147);
70 PRINT:PRINT TAB(11);"[204] O T T O   6 4"
80 PRINT:PRINT
90 PRINT"[215]IE HEISST DAS HEUTIGE [196]ATUM?":INPUT DA$
100 PRINT:PRINT"[194]ITTE [196]RUCKER ANSCHALTEN,"
110 PRINT"[208]APIER EINLEGEN UND EINE [212]ASTE DRUECKEN!"
120 GET A$:IF A$="" THEN 120
130 OPEN 1,4,2
140 PRINT#1,CHR$(27);"@";:REM RESET
150 PRINT#1,CHR$(27);"L";CHR$(10);:REM LINKER RAND
160 PRINT#1,CHR$(27);"[208]";:REM PICA EIN
170 PRINT#1,CHR$(27);"X1";:REM NLQ EIN
180 PRINT#1,CHR$(27);"K";CHR$(1);:REM NLQ-SCHRIFTART
190 PRINT#1,CHR$(27);"W";CHR$(1);:REM BREITDRUCK EIN
200 PRINT#1,"           [204] O T T O   6 4"
210 PRINT#1,CHR$(27);"W";CHR$(0);:REM BREITDRUCK AUS
220 PRINT#1,:PRINT#1,"[198]OLGENDE [204]OTTOZAHLEN WURDEN"
230 PRINT#1,"AM ";DA$;" ERMITTELT:":PRINT#1,
240 FOR RU=1 TO 10
250 PRINT#1,"[211]PIEL";:IF RU<10 THEN PRINT#1," ";
260 PRINT#1,RU;":   ";
270 GOSUB 350
280 PRINT#1,:PRINT#1,
290 NEXT RU
300 CLOSE 1
310 END
320 :
330 :
340 REM LOTTOZAHLEN ERRECHNEN
350 Z=RND(-TI)
360 FOR J=1 TO 49
370 F(J)=0
380 NEXT J
390 FOR X=1 TO 6
400 Z=INT(RND(1)*49)+1
410 IF F(Z)<>0 THEN 400
420 F(Z)=1
430 IF Z<10 THEN PRINT#1," ";
440 PRINT#1, Z;
450 NEXT X
460 RETURN